build.gradle

apply plugin: 'com.android.application'
//apply plugin: 'kotlin-android'



android {

    compileSdkVersion compile_sdk_version
    buildToolsVersion build_tools_version
    defaultConfig {
        applicationId "com.dayu.bigfish"
        minSdkVersion min_sdk_version
        targetSdkVersion target_sdk_version
        versionCode version_code
        versionName verson_name
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
        multiDexEnabled true
        vectorDrawables.useSupportLibrary = true

        javaCompileOptions {
            annotationProcessorOptions {
                arguments = [moduleName: project.getName()]
            }
        }
        ndk {
            abiFilters 'x86', 'armeabi-v7a', 'arm64-v8a','armeabi'
        }
    }

    signingConfigs {
        release {
            keyAlias 'keybigfish'
            keyPassword '123456789'
            storeFile file('app_key.jks')
            storePassword '123456789'
        }
    }

    buildTypes {
        release {
            signingConfig android.signingConfigs.release
            minifyEnabled isReleaseMinify
            shrinkResources isReleaseMinify //是否清理无用资源,依赖于minifyEnabled
            zipAlignEnabled isReleaseMinify //是否启用zipAlign压缩
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }

        debug {
            signingConfig android.signingConfigs.release
            minifyEnabled isDebugMinify
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }

    sourceSets {
        main {
            jniLibs.srcDirs = ['libs']
            assets.srcDirs = ['src/main/assets', 'src/main/assets/']
        }
    }

    aaptOptions {
        cruncherEnabled = false
        useNewCruncher = false
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    dataBinding {
        enabled = true
    }

    lintOptions {
        abortOnError false
        checkReleaseBuilds false
    }
    dexOptions {
        preDexLibraries = false
    }
}


repositories {
    flatDir {
        dirs 'libs'
    }
}

dependencies {
    api fileTree(include: ['*.jar'], dir: 'libs')
    testImplementation 'junit:junit:4.12'
    //ARouter
    annotationProcessor "com.alibaba:arouter-compiler:$arouter_compiler_version"

    if (isMessageModule.toBoolean()) {
        api project(':messageCenter')
    }
    if (isUserModule.toBoolean()) {
        api project(':userCenter')
    }
    if (isOrderModule.toBoolean()) {
        api project(':orderCenter')
    }
    if (isManagerModule.toBoolean()) {
        api project(':managercenter')
    }
//    compile(name: 'orderCenter-debug', ext: 'aar')
//    compile(name: 'userCenter-debug', ext: 'aar')
//    compile(name: 'messageCenter-debug', ext: 'aar')
//    compile(name: 'provider-debug', ext: 'aar')
//    compile(name: 'baseSDK-debug', ext: 'aar')
}